Логическое программирование

Примеры программ на языке Пролог

решить:-старт(S),решить(S,[S],R),reverse(R,P),write(P).
решить(S,R,R):-цель(S),!.
решить(S,P,R):-ход(S,Z),\+ member(Z,P),решить(Z,[Z|P],R).
старт(s(3,3,л,0,0)).
цель(s(_,_,_,3,3)).
лодка(0,1).
лодка(0,2).
лодка(1,1).
лодка(2,0).
лодка(1,0).
безопасно(M,K):-M=:=0; M>=K.
ход(s(ML1,KL1,л,MR1,KR1), s(ML2,KL2,п,MR2,KR2)):-
    лодка(M,K), ML1>=M, KL1>=K,
    ML2 is ML1-M, KL2 is KL1-K, безопасно(ML2,KL2),
    MR2 is MR1+M, KR2 is KR1+K, безопасно(MR2,KR2).
ход(s(ML1,KL1,п,MR1,KR1), s(ML2,KL2,л,MR2,KR2)):-
    ход(s(MR1,KR1,л,ML1,KL1), s(MR2,KR2,п,ML2,KL2)).

% d(+Выражение,+Переменная,-Результат).
d(X,X,1):-!. 
d(C,X,0):-atomic(C). 
d(-U,X,-A):-d(U,X,A). % (-u)’=-u’
d(U+V,X,A+B):-d(U,X,A),d(V,X,B). % (u+v)’=u’+v’.
d(U-V,X,A-B):-d(U,X,A),d(V,X,B). 
d(C*U,X,C*A):-atomic(C),C\=X,d(U,X,A),!.
d(U*V,X,U*B+A*V):-d(U,X,A),d(V,X,B). % (uv)’=uv’+u’v
d(U/V,X,(A*V-U*B)/V?2):-d(U,X,A),d(V,X,B).
d(U?C,X,C*A*U?(C-1)):-d(U,X,A).
d(log(U),X,A/U):-d(U,X,A).

?-d(x*x-2,x,R).
R=x*1+1*x-0

упростить(E,E):-atomic(E),!.
упростить(E,R):-E=..[Op,A],упростить(A,X),s(Op,X,R).
упростить(E,R):-E=..[Op,A,B],
   упростить(A,X),упростить(B,Y),s(Op,X,Y,R).
% таблица упрощений
s(-,X,R):-number(X),R is -X.
s(-,X,-X).
s(+,X,0,X).
s(+,0,X,X).
s(+,X,Y,R):-number(X),number(Y),R is X+Y.
s(+,X*Z,Y*Z,R*Z):-number(X),number(Y),R is X+Y.
. . . % чем больше будет рассмотрено случаев, тем лучше упрощение
s(+,X,Y,X+Y). % ловушка для +
s(*,0,_,0).
s(*,_,0,0).
s(*,X,1,X).
s(*,1,X,X).
. . . % другие правила упрощения
s(*,X,Y,X*Y). % ловушка для *
. . . % правила для – и /

участник('в своем уме').
участник('не в своем уме').
думает('в своем уме',Z):-Z.
думает('не в своем уме',Z):- \+ Z.

?-участник(Король),участник(Королева),
   думает(Король,думает(Королева,Королева=’не в своем уме’)).
Король=’не в своем уме’, Королева=’в своем уме’;
Король=’не в своем уме’, Королева=’не в своем уме’;
no

1. Five colored houses in a row, each with an owner, a pet, cigarettes, and a drink.
   
2. The English lives in the red house.
   
3. The Spanish has a dog.
   
4. They drink coffee in the green house.
   
5. The Ukrainian drinks tea.
   
6. The green house is next to the white house.
   
7. The Winston smoker has a serpent.
   
8. In the yellow house they smoke Kool.
   
9. In the middle house they drink milk.
   
10. The Norwegian lives in the first house from the left.
    
11. The Chesterfield smoker lives near the man with the fox.
    
12. In the house near the house with the horse they smoke Kool.
    
13. The Lucky Strike smoker drinks juice.
    
14. The Japanese smokes Kent.
    
15. The Norwegian lives near the blue house.

% соседи
adjacent(A, B, Ls) :- append(_, [A,B|_], Ls);append(_, [B,A|_], Ls).

?-length(Hs, 5),                                          %  1
member(h(english,_,_,_,red), Hs),                         %  2
member(h(spanish,dog,_,_,_), Hs),                         %  3
member(h(_,_,_,coffee,green), Hs),                        %  4
member(h(ukrainian,_,_,tea,_), Hs),                       %  5
adjacent(h(_,_,_,_,green), h(_,_,_,_,white), Hs),         %  6
member(h(_,snake,winston,_,_), Hs),                       %  7
member(h(_,_,kool,_,yellow), Hs),                         %  8
Hs = [_,_,h(_,_,_,milk,_),_,_],                           %  9
Hs = [h(norwegian,_,_,_,_)|_],                            % 10
adjacent(h(_,fox,_,_,_), h(_,_,chesterfield,_,_), Hs),    % 11
adjacent(h(_,_,kool,_,_), h(_,horse,_,_,_), Hs),          % 12
member(h(_,_,lucky,juice,_), Hs),                         % 13
member(h(japanese,_,kent,_,_), Hs),                       % 14
adjacent(h(norwegian,_,_,_,_), h(_,_,_,_,blue), Hs),      % 15
member(h(Drinker,_,_,water,_), Hs),
member(h(Owner,zebra,_,_,_), Hs).

предложение-->группа_существительного, группа_глагола.
группа_существительного-->артикль, существительное.
группа_глагола-->глагол, группа_существительного; глагол.
артикль-->[the].
существительное-->[apple];[man].
глагол-->[eats];[sings].

?-предложение([the,man,eats,the,apple],[]).
yes

% проверка, что далее операция или конец входной цепочки
isop([],_).
isop([X|_],_):-member(X,[+,-,*,/]).
% перевод выражения в обратной польской записи в обычную инфиксную форму
выр(_,[],_):-!,fail.
выр(X)-->[X],{member(X,[+,-,*,/]),!,fail;true}; % число или идентификатор
         выр(X1),(isop,{!,fail};выр(X2), [Op], {member(Op,[+,-,*,/]),X=..[Op,X1,X2]}).
?-выр(R,[a,1,+,2,*],[]).
R=(a+1)*2